Reorganizing library structure, prep for 2.0.0

2016-07-09 21:17:37 +02:00
parent 4811eb5573
commit ba6bb915c2
1020 changed files with 5 additions and 143645 deletions
@@ -0,0 +1,153 @@
+/**
+ * The MySensors Arduino library handles the wireless radio link and protocol
+ * between your home built sensors/actuators and HA controller of choice.
+ * The sensors forms a self healing radio network with optional repeaters. Each
+ * repeater and gateway builds a routing tables in EEPROM which keeps track of the
+ * network topology allowing messages to be routed to nodes.
+ *
+ * Created by Henrik Ekblad <henrik.ekblad@mysensors.org>
+ * Copyright (C) 2013-2015 Sensnology AB
+ * Full contributor list: https://github.com/mysensors/Arduino/graphs/contributors
+ *
+ * Documentation: http://www.mysensors.org
+ * Support Forum: http://forum.mysensors.org
+ *
+ * This program is free software; you can redistribute it and/or
+ * modify it under the terms of the GNU General Public License
+ * version 2 as published by the Free Software Foundation.
+ *
+ *******************************
+ *
+ * REVISION HISTORY
+ * Version 1.0 - Henrik EKblad
+ * 
+ * DESCRIPTION
+ * This sketch provides an example how to implement a distance sensor using HC-SR04 
+ * Use this sensor to measure KWH and Watt of your house meeter
+ * You need to set the correct pulsefactor of your meeter (blinks per KWH).
+ * The sensor starts by fetching current KWH value from gateway.
+ * Reports both KWH and Watt back to gateway.
+ *
+ * Unfortunately millis() won't increment when the Arduino is in 
+ * sleepmode. So we cannot make this sensor sleep if we also want 
+ * to calculate/report watt-number.
+ * http://www.mysensors.org/build/pulse_power
+ */
+
+// Enable debug prints
+#define MY_DEBUG
+
+// Enable and select radio type attached
+#define MY_RADIO_NRF24
+//#define MY_RADIO_RFM69
+
+#include <SPI.h>
+#include <MySensors.h>  
+
+#define DIGITAL_INPUT_SENSOR 3  // The digital input you attached your light sensor.  (Only 2 and 3 generates interrupt!)
+#define PULSE_FACTOR 1000       // Nummber of blinks per KWH of your meeter
+#define SLEEP_MODE false        // Watt-value can only be reported when sleep mode is false.
+#define MAX_WATT 10000          // Max watt value to report. This filetrs outliers.
+#define CHILD_ID 1              // Id of the sensor child
+
+unsigned long SEND_FREQUENCY = 20000; // Minimum time between send (in milliseconds). We don't wnat to spam the gateway.
+double ppwh = ((double)PULSE_FACTOR)/1000; // Pulses per watt hour
+boolean pcReceived = false;
+volatile unsigned long pulseCount = 0;   
+volatile unsigned long lastBlink = 0;
+volatile unsigned long watt = 0;
+unsigned long oldPulseCount = 0;   
+unsigned long oldWatt = 0;
+double oldKwh;
+unsigned long lastSend;
+MyMessage wattMsg(CHILD_ID,V_WATT);
+MyMessage kwhMsg(CHILD_ID,V_KWH);
+MyMessage pcMsg(CHILD_ID,V_VAR1);
+
+
+void setup()  
+{  
+  // Fetch last known pulse count value from gw
+  request(CHILD_ID, V_VAR1);
+
+  // Use the internal pullup to be able to hook up this sketch directly to an energy meter with S0 output
+  // If no pullup is used, the reported usage will be too high because of the floating pin
+  pinMode(DIGITAL_INPUT_SENSOR,INPUT_PULLUP);
+
+  attachInterrupt(digitalPinToInterrupt(DIGITAL_INPUT_SENSOR), onPulse, RISING);
+  lastSend=millis();
+}
+
+void presentation() {
+  // Send the sketch version information to the gateway and Controller
+  sendSketchInfo("Energy Meter", "1.0");
+
+  // Register this device as power sensor
+  present(CHILD_ID, S_POWER);
+}
+
+void loop()     
+{ 
+  unsigned long now = millis();
+  // Only send values at a maximum frequency or woken up from sleep
+  bool sendTime = now - lastSend > SEND_FREQUENCY;
+  if (pcReceived && (SLEEP_MODE || sendTime)) {
+    // New watt value has been calculated  
+    if (!SLEEP_MODE && watt != oldWatt) {
+      // Check that we dont get unresonable large watt value. 
+      // could hapen when long wraps or false interrupt triggered
+      if (watt<((unsigned long)MAX_WATT)) {
+        send(wattMsg.set(watt));  // Send watt value to gw 
+      }  
+      Serial.print("Watt:");
+      Serial.println(watt);
+      oldWatt = watt;
+    }
+  
+    // Pulse cout has changed
+    if (pulseCount != oldPulseCount) {
+      send(pcMsg.set(pulseCount));  // Send pulse count value to gw 
+      double kwh = ((double)pulseCount/((double)PULSE_FACTOR));     
+      oldPulseCount = pulseCount;
+      if (kwh != oldKwh) {
+        send(kwhMsg.set(kwh, 4));  // Send kwh value to gw 
+        oldKwh = kwh;
+      }
+    }    
+    lastSend = now;
+  } else if (sendTime && !pcReceived) {
+    // No count received. Try requesting it again
+    request(CHILD_ID, V_VAR1);
+    lastSend=now;
+  }
+  
+  if (SLEEP_MODE) {
+    sleep(SEND_FREQUENCY);
+  }
+}
+
+void receive(const MyMessage &message) {
+  if (message.type==V_VAR1) {  
+    pulseCount = oldPulseCount = message.getLong();
+    Serial.print("Received last pulse count from gw:");
+    Serial.println(pulseCount);
+    pcReceived = true;
+  }
+}
+
+void onPulse()     
+{ 
+  if (!SLEEP_MODE) {
+    unsigned long newBlink = micros();  
+    unsigned long interval = newBlink-lastBlink;
+    if (interval<10000L) { // Sometimes we get interrupt on RISING
+      return;
+    }
+    watt = (3600000000.0 /interval) / ppwh;
+    lastBlink = newBlink;
+  } 
+  pulseCount++;
+}
+
+
+