Complete GUI overhaul (from Qt Widgets to Qt Quick Controls 2)

Added chaperone profiles Added separate supersampling sliders for applications/compositor Added asynchronous reprojection on/off switch Merged in Microphone Control Overlay Added Push-to-Talk profiles Updated to OpenVR 1.0.3 Requires at least SteamVR beta 1477423729.
2016-10-28 18:38:05 +02:00
parent 8e815b0ce4
commit e39c240ff5
462 changed files with 64668 additions and 2760 deletions
@@ -0,0 +1,145 @@
+/****************************************************************************
+**
+** Copyright (C) 2016 The Qt Company Ltd.
+** Contact: http://www.qt.io/licensing/
+**
+** This file is part of the Qt Quick Controls 2 module of the Qt Toolkit.
+**
+** $QT_BEGIN_LICENSE:LGPL3$
+** Commercial License Usage
+** Licensees holding valid commercial Qt licenses may use this file in
+** accordance with the commercial license agreement provided with the
+** Software or, alternatively, in accordance with the terms contained in
+** a written agreement between you and The Qt Company. For licensing terms
+** and conditions see http://www.qt.io/terms-conditions. For further
+** information use the contact form at http://www.qt.io/contact-us.
+**
+** GNU Lesser General Public License Usage
+** Alternatively, this file may be used under the terms of the GNU Lesser
+** General Public License version 3 as published by the Free Software
+** Foundation and appearing in the file LICENSE.LGPLv3 included in the
+** packaging of this file. Please review the following information to
+** ensure the GNU Lesser General Public License version 3 requirements
+** will be met: https://www.gnu.org/licenses/lgpl.html.
+**
+** GNU General Public License Usage
+** Alternatively, this file may be used under the terms of the GNU
+** General Public License version 2.0 or later as published by the Free
+** Software Foundation and appearing in the file LICENSE.GPL included in
+** the packaging of this file. Please review the following information to
+** ensure the GNU General Public License version 2.0 requirements will be
+** met: http://www.gnu.org/licenses/gpl-2.0.html.
+**
+** $QT_END_LICENSE$
+**
+****************************************************************************/
+
+import QtQuick 2.6
+import QtQuick.Templates 2.0 as T
+
+T.SpinBox {
+    id: control
+
+    implicitWidth: Math.max(background ? background.implicitWidth : 0,
+                            contentItem.implicitWidth + 2 * padding +
+                            (up.indicator ? up.indicator.implicitWidth : 0) +
+                            (down.indicator ? down.indicator.implicitWidth : 0))
+    implicitHeight: Math.max(contentItem.implicitHeight + topPadding + bottomPadding,
+                             background ? background.implicitHeight : 0,
+                             up.indicator ? up.indicator.implicitHeight : 0,
+                             down.indicator ? down.indicator.implicitHeight : 0)
+    baselineOffset: contentItem.y + contentItem.baselineOffset
+
+    padding: 6
+    leftPadding: padding + (control.mirrored ? (up.indicator ? up.indicator.width : 0) : (down.indicator ? down.indicator.width : 0))
+    rightPadding: padding + (control.mirrored ? (down.indicator ? down.indicator.width : 0) : (up.indicator ? up.indicator.width : 0))
+
+    //! [validator]
+    validator: IntValidator {
+        locale: control.locale.name
+        bottom: Math.min(control.from, control.to)
+        top: Math.max(control.from, control.to)
+    }
+    //! [validator]
+
+    //! [contentItem]
+    contentItem: TextInput {
+        z: 2
+        text: control.textFromValue(control.value, control.locale)
+        opacity: control.enabled ? 1 : 0.3
+
+        font: control.font
+        color: "#353637"
+        selectionColor: "#0066ff"
+        selectedTextColor: "#ffffff"
+        horizontalAlignment: Qt.AlignHCenter
+        verticalAlignment: Qt.AlignVCenter
+
+        readOnly: !control.editable
+        validator: control.validator
+        inputMethodHints: Qt.ImhFormattedNumbersOnly
+
+        Rectangle {
+            x: -6 - (down.indicator ? 1 : 0)
+            y: -6
+            width: control.width - (up.indicator ? up.indicator.width - 1 : 0) - (down.indicator ? down.indicator.width - 1 : 0)
+            height: control.height
+            visible: control.activeFocus
+            color: "transparent"
+            border.color: "#0066ff"
+            border.width: 2
+        }
+    }
+    //! [contentItem]
+
+    //! [up.indicator]
+    up.indicator: Rectangle {
+        x: control.mirrored ? 0 : parent.width - width
+        height: parent.height
+        implicitWidth: 40
+        implicitHeight: 40
+        color: up.pressed ? "#d0d0d0" : "#e0e0e0"
+
+        Rectangle {
+            x: (parent.width - width) / 2
+            y: (parent.height - height) / 2
+            width: parent.width / 3
+            height: 2
+            color: enabled ? "#353637" : "#bdbebf"
+        }
+        Rectangle {
+            x: (parent.width - width) / 2
+            y: (parent.height - height) / 2
+            width: 2
+            height: parent.width / 3
+            color: enabled ? "#353637" : "#bdbebf"
+        }
+    }
+    //! [up.indicator]
+
+    //! [down.indicator]
+    down.indicator: Rectangle {
+        x: control.mirrored ? parent.width - width : 0
+        height: parent.height
+        implicitWidth: 40
+        implicitHeight: 40
+        color: down.pressed ? "#d0d0d0" : "#e0e0e0"
+
+        Rectangle {
+            x: (parent.width - width) / 2
+            y: (parent.height - height) / 2
+            width: parent.width / 3
+            height: 2
+            color: enabled ? "#353637" : "#bdbebf"
+        }
+    }
+    //! [down.indicator]
+
+    //! [background]
+    background: Rectangle {
+        opacity: control.enabled ? 1 : 0.3
+        implicitWidth: 140
+        border.color: "#e0e0e0"
+    }
+    //! [background]
+}