ykearaandJames R
65b5aace06
* add nlhomann json header * add get scene app fn * add get current binding and related logic * add save binding file to settings folder * apply binding fn added fixed uid bug * add button logic to QML, add enable Bind Setting * add finding logic for all custom bind * fix minor qml issues * fix get controllername bug, fix bug with save bind * fix regex issue * change webrequest for selectconfig * change to properly urlify path to send * fix race condition web requests * change steamvr tab qml formatting * change color scheme * change colors of icons to text color * change bind qml better for better ux * add possible workaround for space drag issues * add deact color to pushbutton * increment version * adjust button size in movecenter * move nlhomann json * fix PKGBUILD to include missing dependency (#606) (#613) It turns out qt5-websockets needs to be included for a successful build. Co-authored-by: James R <71466513+ColdIce1605@users.noreply.github.com> * fix warning * improved logging messages around perapp bindings * improve getsceneappID logging * add HMD based controller Finding * improve logging controller name * change logging around initial chaperone calibration * increment version * improve logging/error handling around sceneappid failures * added fallback for getting scene app by pid * update version string * update documentation Co-authored-by: James R <71466513+ColdIce1605@users.noreply.github.com>
158 lines
5.5 KiB
Plaintext
158 lines
5.5 KiB
Plaintext
SOURCES += src/main.cpp\
|
|
src/overlaycontroller.cpp \
|
|
src/tabcontrollers/AudioTabController.cpp \
|
|
src/tabcontrollers/ChaperoneTabController.cpp \
|
|
src/tabcontrollers/FixFloorTabController.cpp \
|
|
src/tabcontrollers/MoveCenterTabController.cpp \
|
|
src/tabcontrollers/SettingsTabController.cpp \
|
|
src/tabcontrollers/StatisticsTabController.cpp \
|
|
src/tabcontrollers/SteamVRTabController.cpp \
|
|
src/tabcontrollers/UtilitiesTabController.cpp \
|
|
src/tabcontrollers/VideoTabController.cpp \
|
|
src/tabcontrollers/RotationTabController.cpp\
|
|
src/utils/ChaperoneUtils.cpp \
|
|
src/openvr/openvr_init.cpp \
|
|
src/openvr/ivrinput.cpp \
|
|
src/openvr/ovr_settings_wrapper.cpp \
|
|
src/openvr/ovr_overlay_wrapper.cpp \
|
|
src/openvr/ovr_system_wrapper.cpp \
|
|
src/openvr/lh_console_util.cpp \
|
|
src/openvr/ovr_application_wrapper.cpp \
|
|
src/utils/setup.cpp \
|
|
src/utils/paths.cpp \
|
|
src/utils/FrameRateUtils.cpp \
|
|
src/keyboard_input/keyboard_input.cpp \
|
|
src/keyboard_input/input_parser.cpp \
|
|
src/settings/settings.cpp \
|
|
src/settings/settings_object.cpp \
|
|
src/alarm_clock/vr_alarm.cpp \
|
|
src/utils/update_rate.cpp \
|
|
|
|
|
|
|
|
HEADERS += src/overlaycontroller.h \
|
|
src/tabcontrollers/AudioTabController.h \
|
|
src/tabcontrollers/ChaperoneTabController.h \
|
|
src/tabcontrollers/FixFloorTabController.h \
|
|
src/tabcontrollers/MoveCenterTabController.h \
|
|
src/tabcontrollers/SettingsTabController.h \
|
|
src/tabcontrollers/StatisticsTabController.h \
|
|
src/tabcontrollers/SteamVRTabController.h \
|
|
src/tabcontrollers/UtilitiesTabController.h \
|
|
src/tabcontrollers/VideoTabController.h \
|
|
src/tabcontrollers/audiomanager/AudioManager.h \
|
|
src/tabcontrollers/RotationTabController.h\
|
|
src/keyboard_input/keyboard_input.h \
|
|
src/media_keys/media_keys.h \
|
|
src/utils/Matrix.h \
|
|
src/utils/ChaperoneUtils.h \
|
|
src/quaternion/quaternion.h \
|
|
src/openvr/openvr_init.h \
|
|
src/openvr/ivrinput_action.h \
|
|
src/openvr/ivrinput_manifest.h \
|
|
src/openvr/ivrinput_action_set.h \
|
|
src/openvr/ivrinput_input_source.h \
|
|
src/openvr/ivrinput.h \
|
|
src/openvr/ovr_settings_wrapper.h \
|
|
src/openvr/ovr_overlay_wrapper.h \
|
|
src/openvr/ovr_system_wrapper.h \
|
|
src/openvr/ovr_application_wrapper.h \
|
|
src/openvr/lh_console_util.h \
|
|
src/utils/setup.h \
|
|
src/utils/paths.h \
|
|
src/utils/FrameRateUtils.h \
|
|
src/keyboard_input/input_parser.h \
|
|
src/keyboard_input/input_sender.h \
|
|
src/settings/settings.h \
|
|
src/settings/internal/setting_value.h \
|
|
src/settings/internal/settings_internal.h \
|
|
src/settings/internal/settings_controller.h \
|
|
src/settings/internal/specific_setting_value.h \
|
|
src/settings/settings_object.h \
|
|
src/settings/internal/settings_object_data.h \
|
|
src/alarm_clock/vr_alarm.h \
|
|
src/settings/internal/settings_object_data.h \
|
|
src/settings/internal/settings_object_data.h \
|
|
src/utils/update_rate.h \
|
|
|
|
|
|
win32 {
|
|
SOURCES += src/tabcontrollers/audiomanager/AudioManagerWindows.cpp \
|
|
src/keyboard_input/input_sender_win.cpp \
|
|
src/media_keys/media_keys_win.cpp
|
|
HEADERS += src/tabcontrollers/audiomanager/AudioManagerWindows.h
|
|
}
|
|
|
|
unix:!macx {
|
|
!noX11 {
|
|
message(X11 features enabled.)
|
|
SOURCES += src/keyboard_input/input_sender_X11.cpp
|
|
CONFIG += x11
|
|
LIBS += -lXtst
|
|
}
|
|
else {
|
|
message(X11 features disabled.)
|
|
SOURCES += src/keyboard_input/input_sender_dummy.cpp
|
|
}
|
|
|
|
!noDBUS {
|
|
message(DBUS features enabled.)
|
|
SOURCES += src/media_keys/media_keys_dbus.cpp
|
|
QT += dbus
|
|
}
|
|
else {
|
|
message(DBUS features disabled.)
|
|
SOURCES += src/media_keys/media_keys_dummy.cpp
|
|
}
|
|
|
|
!noPulse {
|
|
message(PulseAudio features enabled.)
|
|
SOURCES += src/tabcontrollers/audiomanager/AudioManagerPulse.cpp
|
|
HEADERS += src/tabcontrollers/audiomanager/AudioManagerPulse.h \
|
|
src/tabcontrollers/audiomanager/AudioManagerPulse_internal.h
|
|
LIBS += -lpulse
|
|
}
|
|
else {
|
|
message(PulseAudio features disabled.)
|
|
SOURCES += src/tabcontrollers/audiomanager/AudioManagerDummy.cpp
|
|
HEADERS += src/tabcontrollers/audiomanager/AudioManagerDummy.h
|
|
}
|
|
}
|
|
|
|
macx {
|
|
SOURCES += src/keyboard_input/input_sender_dummy.cpp \
|
|
src/media_keys/media_keys_dummy.cpp \
|
|
src/tabcontrollers/audiomanager/AudioManagerDummy.cpp
|
|
HEADERS += src/tabcontrollers/audiomanager/AudioManagerDummy.h
|
|
|
|
}
|
|
|
|
win32-msvc {
|
|
INCLUDEPATH += third-party/openvr/headers \
|
|
third-party/easylogging++ \
|
|
third-party/policyconfig
|
|
}
|
|
|
|
win32-clang-msvc {
|
|
QMAKE_CXXFLAGS += /imsvc "$$PWD/../../third-party/openvr/headers"
|
|
QMAKE_CXXFLAGS += /imsvc "$$PWD/../../third-party/easylogging++"
|
|
QMAKE_CXXFLAGS += /imsvc "$$PWD/../../third-party/policyconfig"
|
|
}
|
|
|
|
# Anything g++ or clang
|
|
# In order to suppress warnings in third party headers
|
|
*clang|*clang-g++|*clang-libc++|*g++* {
|
|
#Force Linux to look into the current dir for the OpenVR lib
|
|
QMAKE_LFLAGS += '-Wl,-rpath,\'\$$ORIGIN\''
|
|
|
|
QMAKE_CXXFLAGS += -isystem $$[QT_INSTALL_HEADERS]
|
|
QMAKE_CXXFLAGS += -isystem $$[QT_INSTALL_HEADERS]/QtCore
|
|
QMAKE_CXXFLAGS += -isystem $$[QT_INSTALL_HEADERS]/QtGui
|
|
|
|
QMAKE_CXXFLAGS += -isystem $$PWD/../../third-party/openvr/headers
|
|
QMAKE_CXXFLAGS += -isystem $$PWD/../../third-party/easylogging++
|
|
}
|
|
|
|
# easylogging++ used to be a header only lib. Now requires easylogging++.cc
|
|
SOURCES += third-party/easylogging++/easylogging++.cc
|