matzman
e39c240ff5
Added chaperone profiles Added separate supersampling sliders for applications/compositor Added asynchronous reprojection on/off switch Merged in Microphone Control Overlay Added Push-to-Talk profiles Updated to OpenVR 1.0.3 Requires at least SteamVR beta 1477423729.
144 lines
5.3 KiB
QML
144 lines
5.3 KiB
QML
/****************************************************************************
|
|
**
|
|
** Copyright (C) 2016 The Qt Company Ltd.
|
|
** Contact: http://www.qt.io/licensing/
|
|
**
|
|
** This file is part of the Qt Quick Controls 2 module of the Qt Toolkit.
|
|
**
|
|
** $QT_BEGIN_LICENSE:LGPL3$
|
|
** Commercial License Usage
|
|
** Licensees holding valid commercial Qt licenses may use this file in
|
|
** accordance with the commercial license agreement provided with the
|
|
** Software or, alternatively, in accordance with the terms contained in
|
|
** a written agreement between you and The Qt Company. For licensing terms
|
|
** and conditions see http://www.qt.io/terms-conditions. For further
|
|
** information use the contact form at http://www.qt.io/contact-us.
|
|
**
|
|
** GNU Lesser General Public License Usage
|
|
** Alternatively, this file may be used under the terms of the GNU Lesser
|
|
** General Public License version 3 as published by the Free Software
|
|
** Foundation and appearing in the file LICENSE.LGPLv3 included in the
|
|
** packaging of this file. Please review the following information to
|
|
** ensure the GNU Lesser General Public License version 3 requirements
|
|
** will be met: https://www.gnu.org/licenses/lgpl.html.
|
|
**
|
|
** GNU General Public License Usage
|
|
** Alternatively, this file may be used under the terms of the GNU
|
|
** General Public License version 2.0 or later as published by the Free
|
|
** Software Foundation and appearing in the file LICENSE.GPL included in
|
|
** the packaging of this file. Please review the following information to
|
|
** ensure the GNU General Public License version 2.0 requirements will be
|
|
** met: http://www.gnu.org/licenses/gpl-2.0.html.
|
|
**
|
|
** $QT_END_LICENSE$
|
|
**
|
|
****************************************************************************/
|
|
|
|
import QtQuick 2.6
|
|
import QtQuick.Window 2.2
|
|
import QtQuick.Controls 2.0
|
|
import QtQuick.Templates 2.0 as T
|
|
import QtQuick.Controls.Universal 2.0
|
|
|
|
T.ComboBox {
|
|
id: control
|
|
|
|
implicitWidth: Math.max(background ? background.implicitWidth : 0,
|
|
contentItem.implicitWidth + leftPadding + rightPadding)
|
|
implicitHeight: Math.max(background ? background.implicitHeight : 0,
|
|
Math.max(contentItem.implicitHeight,
|
|
indicator ? indicator.implicitHeight : 0) + topPadding + bottomPadding)
|
|
baselineOffset: contentItem.y + contentItem.baselineOffset
|
|
|
|
spacing: 10
|
|
padding: 12
|
|
topPadding: padding - 7
|
|
rightPadding: padding - 2
|
|
bottomPadding: padding - 5
|
|
|
|
//! [delegate]
|
|
delegate: ItemDelegate {
|
|
width: control.width
|
|
text: control.textRole ? (Array.isArray(control.model) ? modelData[control.textRole] : model[control.textRole]) : modelData
|
|
highlighted: control.highlightedIndex === index
|
|
}
|
|
//! [delegate]
|
|
|
|
//! [indicator]
|
|
indicator: Image {
|
|
x: control.mirrored ? control.leftPadding : control.width - width - control.rightPadding
|
|
y: control.topPadding + (control.availableHeight - height) / 2
|
|
source: "image://universal/downarrow/" + (!control.enabled ? control.Universal.baseLowColor : control.Universal.baseMediumHighColor)
|
|
sourceSize.width: width
|
|
sourceSize.height: height
|
|
}
|
|
//! [indicator]
|
|
|
|
//! [contentItem]
|
|
contentItem: Text {
|
|
leftPadding: control.mirrored && control.indicator ? control.indicator.width + control.spacing : 0
|
|
rightPadding: !control.mirrored && control.indicator ? control.indicator.width + control.spacing : 0
|
|
|
|
text: control.displayText
|
|
font: control.font
|
|
horizontalAlignment: Text.AlignLeft
|
|
verticalAlignment: Text.AlignVCenter
|
|
elide: Text.ElideRight
|
|
|
|
opacity: enabled ? 1.0 : 0.2
|
|
color: control.Universal.foreground
|
|
}
|
|
//! [contentItem]
|
|
|
|
//! [background]
|
|
background: Rectangle {
|
|
implicitWidth: 120
|
|
implicitHeight: 32
|
|
|
|
border.width: 2 // ComboBoxBorderThemeThickness
|
|
border.color: !control.enabled ? control.Universal.baseLowColor :
|
|
control.pressed || popup.visible ? control.Universal.baseMediumLowColor : control.Universal.baseMediumLowColor
|
|
color: !control.enabled ? control.Universal.baseLowColor :
|
|
control.pressed || popup.visible ? control.Universal.listMediumColor : control.Universal.altMediumLowColor
|
|
|
|
Rectangle {
|
|
x: 2
|
|
y: 2
|
|
width: parent.width - 4
|
|
height: parent.height - 4
|
|
|
|
visible: control.visualFocus
|
|
color: control.Universal.accent
|
|
opacity: control.Universal.theme === Universal.Light ? 0.4 : 0.6
|
|
}
|
|
}
|
|
//! [background]
|
|
|
|
//! [popup]
|
|
popup: T.Popup {
|
|
width: control.width
|
|
implicitHeight: Math.min(396, listview.contentHeight)
|
|
topMargin: 8
|
|
bottomMargin: 8
|
|
|
|
Universal.theme: control.Universal.theme
|
|
Universal.accent: control.Universal.accent
|
|
|
|
contentItem: ListView {
|
|
id: listview
|
|
clip: true
|
|
model: control.popup.visible ? control.delegateModel : null
|
|
currentIndex: control.highlightedIndex
|
|
|
|
T.ScrollIndicator.vertical: ScrollIndicator { }
|
|
}
|
|
|
|
background: Rectangle {
|
|
color: control.Universal.chromeMediumLowColor
|
|
border.color: control.Universal.chromeHighColor
|
|
border.width: 1 // FlyoutBorderThemeThickness
|
|
}
|
|
}
|
|
//! [popup]
|
|
}
|