Files
OpenVR-AdvancedSettings-frame/build_scripts/qt/compilers/gcc.pri
T
Vasily 9cfaf68a92 Update GCC compiler to not use hardcoded g++-7
Newer versions of Ubuntu ship with >g++-7, so there will be less of a
need as time goes on to perform this hack.
2019-04-22 09:56:50 +02:00

27 lines
885 B
Plaintext

# Makes sure the "g++" command used to invoke the compilation is abvove version 7.
# If it's at or above version 7 then we can use the default g++, otherwise we'll
# specifically need g++-7.
system( g++ --version | grep -e " [0-9]\?[0-9]\?[6-9].[0-9]" ) {
message('g++' version is not above 7. Manually using 'g++-7'.)
!system(g++-7 --version) {
error(At least g++-7 required.)
}
#g++-7 is needed for C++17 features. travis does not supply this by default.
QMAKE_CXX = g++-7
}
include(clang-gcc-common-switches.pri)
QMAKE_CXXFLAGS += -Wpedantic
QMAKE_CXXFLAGS += -Werror
# GCC only switches
QMAKE_CXXFLAGS += -Wduplicated-branches -Wduplicated-cond -Wlogical-op -Wrestrict -Wnull-dereference
# Sign conversion warns on auto generated Qt MOC files.
QMAKE_CXXFLAGS += -Wconversion -Wno-sign-conversion
QMAKE_CXXFLAGS += -Wzero-as-null-pointer-constant