Move windeployqt to Qmake

`qmake` is better suited for finding `windeployqt`, since it's in the same
directory as `qmake` on windows.

`qmake` is also better suited for finding the build target
(release/debug) vs third party scripts.

`windeployqt` is being forced to run in `cmd` because the syntax is
different for running executables in powershell, which means
`windeployqt` won't be executed and runtime or package errors will
occur.

With the removal of the windeployqt call the deploy step is no longer
needed for building on Windows, since all previous deploy tasks are now
handle by Qmake.

advancedSettings.pro

@@ -65,3 +65,28 @@ packageFilesCopy.path = $$COPY_DEST_DIR
 win32:openvrApiCopy.files = third-party/openvr/bin/win64/openvr_api.dll
 unix:openvrApiCopy.files = third-party/openvr/lib/linux64/libopenvr_api.so
 openvrApiCopy.path = $$COPY_DEST_DIR
+
+# Deploy resources and DLLs to exe dir on Windows
+win32 {
+    WINDEPLOYQT_LOCATION = $$dirname(QMAKE_QMAKE)/windeployqt.exe
+
+    CONFIG( debug, debug|release ) {
+        WINDEPLOYQT_BUILD_TARGET += "--debug"
+    } else {
+        WINDEPLOYQT_BUILD_TARGET += "--release"
+    }
+
+    WINDEPLOYQT_OPTIONS = --dir $$COPY_DEST_DIR/qtdata \
+                          --libdir $$COPY_DEST_DIR \
+                          --plugindir $$COPY_DEST_DIR/qtdata/plugins \
+                          --no-system-d3d-compiler \
+                          --no-opengl-sw \
+                          $$WINDEPLOYQT_BUILD_TARGET \
+                          --qmldir $$PWD/src/res/qml \
+                          $$COPY_DEST_DIR/AdvancedSettings.exe
+    WINDEPLOYQT_FULL_LINE = "$$WINDEPLOYQT_LOCATION $$WINDEPLOYQT_OPTIONS"
+
+    # Force windeployqt to run in cmd, because powershell has different syntax
+    # for running executables.
+    QMAKE_POST_LINK = cmd /c $$WINDEPLOYQT_FULL_LINE
+}